Portenta H7 with Cat. M1/NB shield does not connect over LTE Cat-M1 | Telit Cinterion IoT Developer Community

June 30, 2022 - 1:40pm, 567 views

While working with the Arduino Portenta H7 Cat. M1/NB shield, I found out that the Thales Cinterion TX62 cellular modem only connects over NB-IoT, NOT over LTE Cat-M1.

I'm using th Arduino Portenta library, with the below code snippet:

#include <GSM.h>

char pin[]      = SECRET_PIN;       //example "1234"
char apn[]      = SECRET_APN;       //example "live.provider.com"
char username[] = SECRET_USERNAME;
char pass[]     = SECRET_PASSWORD;

void setup() {
  Serial.begin(115200);
  while(!Serial) {}
  GSM.debug(Serial);

    if(GSM.begin(pin, apn, username, pass, CATM1)){
        Serial.println("connected");
    }
}

I defined the use of CATM1 in the GSM.begin(), but it doesn't connect and eventually moves to NB-IoT after a few tries, as shown in the logs:

AT^SXRAT=7
+CME ERROR: unknown
AT error code 0
CellularContext connect
Setup SIM (timeout 10000 ms)
...
+CEREG: 2<cr><ln><cr><ln>+CEREG: 5,"2D5B","0187FB66",9

Any pointers on how to make the shield connect over LTE CAT-M1?

I haven't managed to directly communicate with the cellular modem yet, allowing me to send AT Commands to the board directly. Any support to make this work would also be appreciated.

Thanks,
Laurens

Comment

Bartłomiej Gema...

Jun 30 2022 - 3:29pm

Hello,

Are you sure that this SIM should work in LTE Cat-M1? Please check the available networks with AT+COPS=? And also check AT+CGDCONT?, make sure that you use the right APN and delete the other entries. It should be possible to set AT^SXRAT=7, please check the current setting with AT^SXRAT?, reboot the module and try again. Please also check AT^SCFG? output to verify the bands enabled.
I suppose that you should get the board documentation from Arduino. I'll try to find some documentation regarding your question.

Best regards,
Bartłomiej

Like
1
Log in or register to post comments

laurens

Jul 5 2022 - 7:47pm

Thanks for the support. Turned out that the Cat M1 bands were disabled:

AT^SCFG="Radio/Band/CatM"
^SCFG: "Radio/Band/CatM","00000000"

Which was solved after entering the following command (8000 is for B20):

AT^SCFG="Radio/Band/CatM","80000"  
^SCFG: "Radio/Band/CatM","00080000"

For reference, below the Arduino code to directly communicate from your PC to the Cinterion TX62 modem.

 /*
  SerialPassthrough sketch

  Some boards, like the Arduino 101, the MKR1000, Zero, or the Micro, have one
  hardware serial port attached to Digital pins 0-1, and a separate USB serial
  port attached to the IDE Serial Monitor. This means that the "serial
  passthrough" which is possible with the Arduino UNO (commonly used to interact
  with devices/shields that require configuration via serial AT commands) will
  not work by default.

  This sketch allows you to emulate the serial passthrough behaviour. Any text
  you type in the IDE Serial monitor will be written out to the serial port on
  Digital pins 0 and 1, and vice-versa.

  On the 101, MKR1000, Zero, and Micro, "Serial" refers to the USB Serial port
  attached to the Serial Monitor, and "Serial1" refers to the hardware serial
  port attached to pins 0 and 1. This sketch will emulate Serial passthrough
  using those two Serial ports on the boards mentioned above, but you can change
  these names to connect any two serial ports on a board that has multiple ports.

  created 23 May 2016
  by Erik Nyquist
*/
#include "mbed.h"

#define MBED_CONF_GEMALTO_CINTERION_RTS   PI_10
#define MBED_CONF_GEMALTO_CINTERION_TX    PA_0
#define MBED_CONF_GEMALTO_CINTERION_RX    PI_9
mbed::DigitalOut on(PJ_7, 1);
mbed::DigitalOut rts(MBED_CONF_GEMALTO_CINTERION_RTS, 0);

arduino::UART SerialGemalto(MBED_CONF_GEMALTO_CINTERION_TX, MBED_CONF_GEMALTO_CINTERION_RX, NC, NC);

void setup() {
  Serial.begin(115200);
  //while(!Serial)
  SerialGemalto.begin(115200);
  on = 0;
  delay(200);
  on = 1;
   
  delay(200);
  pinMode(PJ_7,INPUT_PULLDOWN);

}

void loop() {
  if (Serial.available()) {      // If anything comes in Serial (USB),
    char c = Serial.read();
    SerialGemalto.write(c);   // read it and send it out Serial1 (pins 0 & 1)
    //Serial1.write(c);
  }

  if (SerialGemalto.available()) {     // If anything comes in Serial1 (pins 0 & 1)
    char c = SerialGemalto.read();
    Serial.write(c);   // read it and send it out Serial (USB)
  }
}

Like
0
Log in or register to post comments

Bartłomiej Gema...

Jul 6 2022 - 9:55am

Thank you for the feedback.
Great that the code was helpful.

BR,
Bartłomiej

Like
0
Log in or register to post comments

You are here

Portenta H7 with Cat. M1/NB shield does not connect over LTE Cat-M1 | Telit Cinterion IoT Developer Community